hi everyone
I want to do as follows:
* click a “red” button
* write in textarea with red color font
* click “blue” button
* write in textarea with blue color font
Isn’t this possible in flash 10 using AS3 ??????

I tried using setTextFormat but the problem is i have to have text before inserting format on that.

Please somebody tell me how to do this?????
Thanks alot in advance
Regards

Below is the solution after understanding his problem. It took me 30 minutes to get to this solution. At first, I used KeyboardEvent.DOWN but it does not work well since it takes into account of all keyboard button clicks (includes arrow keys). Using the replaceText function provided in TextField does not solve it as it resets all htmlText colors and convert it into normal text.

The key solution is the Event.CHANGE that tracks changes done within the textfield. This means user entering new text or removing text, but its not affected by user pressing the arrow keys or ESC. It also solves the replaceText method and it does not require my side to find out the exact caretIndex to add the new html text with the color settings like:

this._textField.htmlText += "<font color='#FF0000'>red</font>";

Preview of the SWF: http://megaswf.com/serve/56321/

package
{
	import flash.display.DisplayObject;
	import flash.display.Sprite;
	import flash.events.Event;
	import flash.events.KeyboardEvent;
	import flash.events.MouseEvent;
	import flash.text.TextField;
	import flash.text.TextFieldAutoSize;
	import flash.text.TextFieldType;
	import flash.text.TextFormat;

	/**
	 * ...
	 * @author Ayumilove
	 */
	public class Main extends Sprite
	{

		private var _red:Sprite;
		private var _blue:Sprite;
		private var _textField:TextField;
		private var _textFormat:TextFormat;
		private var _isColorSwitched:Boolean;
		private var _currentColor:String;

		private var _boldTx:TextField;
		private var _italicTx:TextField;

		public function Main():void
		{
			if (super.stage) this.init();
			else super.addEventListener(Event.ADDED_TO_STAGE, this.init);
		}

		private function init(event:Event = null):void
		{
			super.removeEventListener(Event.ADDED_TO_STAGE, this.init);
			this.initColorButton();
			this.initTextField();
		}

		private function initColorButton():void
		{
			this._red = new Sprite();
			this._blue = new Sprite();
			var buttons:Array = [this._red,this._blue];
			var colors:Array = [0xFF0000, 0x0000FF];
			var sp:Sprite;
			var i:int = buttons.length;;

			while (i--)
			{
				sp = buttons[i];
				sp.x = 10;
				sp.y = 25 * i + 125;
				sp.graphics.beginFill(colors[i]);
				sp.graphics.drawRect(0, 0, 20, 20);
				sp.graphics.endFill();
				super.addChild(sp);
				sp.addEventListener(MouseEvent.CLICK, this.switchTextFontColor);
			}
		}

		private function initTextField():void
		{
			this._textFormat = new TextFormat();
			this._textFormat.size = 20;

			this._textField = new TextField();
			this._textField.defaultTextFormat = this._textFormat;
			this._textField.x =
			this._textField.y = 10;
			this._textField.border = true;
			this._textField.type = TextFieldType.INPUT;
			this._textField.autoSize = TextFieldAutoSize.LEFT;
			this._textField.htmlText = "Hello Ayumilove";
			this._textField.addEventListener(Event.CHANGE, this.changeHandler);
			super.addChild(this._textField);

			this._boldTx = new TextField();
			this._boldTx.mouseEnabled = true;
			this._boldTx.selectable = false;
			this._boldTx.htmlText = "<b>Bold</b>";
			this._boldTx.x = 10;
			this._boldTx.y = 175;
			this._boldTx.addEventListener(MouseEvent.CLICK, this.updateTextFormat);
			super.addChild(this._boldTx);

			this._italicTx = new TextField();
			this._italicTx.mouseEnabled = true;
			this._italicTx.selectable = false;
			this._italicTx.htmlText = "<i>Italic</i>";
			this._italicTx.x = 10;
			this._italicTx.y = 200;
			this._italicTx.addEventListener(MouseEvent.CLICK, this.updateTextFormat);
			super.addChild(this._italicTx);
		}

		private function switchTextFontColor(event:MouseEvent):void
		{
			stage.focus = this._textField;
			this._textFormat.color = this.getColorByColorButton(event.currentTarget as Sprite);
		}

		private function changeHandler(event:Event):void
		{
			if (!this._textField.text.length) return;

			this._textField.setTextFormat(
				this._textFormat,
				this._textField.caretIndex -1 ,
				this._textField.caretIndex);
		}

		private function getColorByColorButton(dsp:DisplayObject):uint
		{
			switch(dsp)
			{
				case this._red	: return 0xFF0000;
				case this._blue	: return 0x0000FF;
				default			: return 0x000000;
			}
		}

		private function updateTextFormat(event:MouseEvent):void
		{
			stage.focus = this._textField;

			switch(event.target)
			{
				case this._boldTx 	: this._textFormat.bold = !this._textFormat.bold; break;
				case this._italicTx	: this._textFormat.italic = !this._textFormat.italic; break;
				default				: break;
			}

		}
	}
}

A Kirupan (andy310584) post a problem on setting each image position based on the category.

Hello to everyone.
let’s go straight to the problem.
i have an xml that’s looks like this:

<?xml version="1.0" encoding="utf-8"?>
<pics>
    <category name="categoria1">
        <image NAME="1" PATH="images/1.jpg" DESCRIPTION="SALAM"/>
        <image NAME="2" PATH="images/2.jpg" DESCRIPTION="SALAM2"/>
        <image NAME="9" PATH="images/3.jpg" DESCRIPTION="SALAM3"/>
    </category>
    <category name="categoria2">
        <image NAME="3" PATH="images/4.jpg" DESCRIPTION="SALAM4"/>
        <image NAME="4" PATH="images/5.jpg" DESCRIPTION="SALAM5"/>
        <image NAME="5" PATH="images/6.jpg" DESCRIPTION="SALAM6"/>
        <image NAME="5" PATH="images/7.jpg" DESCRIPTION="SALAM7"/>
    </category>
    <category name="categoria3">
        <image NAME="6" PATH="images/8.jpg" DESCRIPTION="SALAM8"/>
        <image NAME="7" PATH="images/9.jpg" DESCRIPTION="SALAM9"/>
        <image NAME="8" PATH="images/10.jpg" DESCRIPTION="SALAM10"/>
    </category>
</pics>

As you can see i have categories and inside the categories i have the pictures. what i want to do is every category to be displayed with a lower y position than the previous category. and in every category the picture to be arrange in the way presented in the picture below (x position for images = 0, the picture is just to make an idea).

I know that i have to use for(i=0….) and for(j=0…) but i can’t figure how. My AS3 code looks like this:

import fl.transitions.Tween;
import fl.transitions.easing.*;

var _total:int = 0;
var _categories:XMLList = null;
var _subCategories:XMLList = null;
var _loaders:Array = new Array();
var _counter:int = 0;
var _next:int = 0;
var _tween:Tween = null;
var _container:Sprite = new Sprite();
var _text:TextField = new TextField();

var _loader:URLLoader = new URLLoader();
_loader.load(new URLRequest("gallery.xml"));
_loader.addEventListener(Event.COMPLETE, Complete, false, 0, true);

function Complete(e:Event):void {
    var _xml:XML = new XML(e.target.data);

    _loader.removeEventListener(Event.COMPLETE, Complete);
    _loader = null;
    _categories = _xml.category;
    _total= _categories.length();

    LoadImages();
}

function LoadImages():void {
    for (var i:int = 0; i < _total; i++) {
        var _url:String = _categories.image[i].@PATH;
        var _loader:Loader = new Loader();
        _loader.load(new URLRequest(_url));
        _loader.contentLoaderInfo.addEventListener(Event.COMPLETE, ImageLoaded);
        _loaders.push(_loader);
    }
}

Solution

trace("/////////////// Function4: ///////////////");

xml.category.(loadImageByCategory(@name,image.@PATH));

function loadImageByCategory(categoryId:String,xmllist:XMLList):void
{
	var yPos:int = this.getYPosByCategory(categoryId);
	this.loadImageWithYPos(yPos,xmllist);
}

function getYPosByCategory(categoryId:String):int
{
	switch(categoryId)
	{
		case "categoria1" : trace("Set image y:100"); return 100;
		case "categoria2" : trace("Set image y:200"); return 200;
		case "categoria3" : trace("Set image y:300"); return 300;
		default: return 0;
	}
}

function loadImageWithYPos(yPos:int,xmllist:XMLList):void
{
	var l:int = xmllist.length();
	var i:int;

	for(i; i<l; i++)
	{
		trace("yPos: " + yPos + " - Image Path: " + xmllist[i]);
	}
}

XML Traces

/////////////// Function4: ///////////////
Set image y:100
yPos: 100 - Image Path: images/1.jpg
yPos: 100 - Image Path: images/2.jpg
yPos: 100 - Image Path: images/3.jpg
Set image y:200
yPos: 200 - Image Path: images/4.jpg
yPos: 200 - Image Path: images/5.jpg
yPos: 200 - Image Path: images/6.jpg
yPos: 200 - Image Path: images/7.jpg
Set image y:300
yPos: 300 - Image Path: images/8.jpg
yPos: 300 - Image Path: images/9.jpg
yPos: 300 - Image Path: images/10.jpg

Effects
Poison, Death, Doom, Syphon, Berserk, AccuracyDown, EvadeDown, MagicAttackDown, WeaponAttackDown

Enemy weak against Earth receives extra damage from hero’s
weapon earth element.

Equipments are use to amplify/deamplify a value in hero similarly
to Epic Battle Fantasy 3.

Distribution Benefits
1 : 20%
2 : 40%
3 : 60%
4 : 80%
5 : 100%
6 : 120%
7 : 140%
8 : 160%
9 : 180%

Every specialty that an equipment has reduces 30% benefit.
For instance:
A weapon may cast an ice-element skill at 15% rate (-30%)
A weapon may cast an ice-element skill at 30% rate (-60%)
A weapon may cast an ice-element skill at 45% rate (-90%)

All entities has these stats (equipment as stat boosters)
Health
Magic
Weapon Attack
Weapon Defense
Magic Attack
Magic Defense
Accuracy
Evade

Below is the walkthrough on setting up your project packaging
source path so you avoid that 5001 error.

Assuming your project folder is located in your C drive C:\
Let’s call it PackageTest folder for this scenario C:\PackageTest
Your fla is place inside C:\PackageTest

Within the ‘PackageTest’ folder contains a ‘com’ folder
The ‘com’ folder contains another folder called ‘ayumilove’
‘ayumilove’ folder contains the Game.as file

In short:
c:\PackageTest\com\ayumilove\Game.as

Open Adobe Flash IDE (integrated development environment)
and open up your .fla inside.

Go to File, Publish Settings, switch to Flash Tab and click Settings
This pops a new window ‘Advanced ActionScript 3.0 Settings’

Switch to Source Path tab.
Make sure the list has a dot .
A dot represents the current location of the .fla that resides
which is PackageTest. Adobe Flash will start looking into this
location to search for the .as files.

However, our Game.as is located in com.ayumilove
2 more folders deeper within PackageTest

So make sure that your .as class has that included in package name

package com.ayumilove
{
	import flash.display.MovieClip;

	public class Game extends MovieClip
	{

		public function Game()
		{
			trace("Game Created");
		}

	}

}

My Game.as will be the Main.as for the .fla
So, returning back to the Adobe Flash Timeline,
Open up your Properties Panel (CTRL+F3) or Windows, Properties
Click on the stage, and set the class in Properties Panel as
com.ayumilove.Game (NOT com.ayumilove.Game.as)

CTRL+ENTER to test the file. It works!

Extra notes:
Assuming the location of both files are switched,
meaning the Game.as now resides in the PackageTest
and the .fla location now resides in PackageTest.com.ayumilove

You will need to use the double dot to move up 1 folder.
To move up multiple folder, use the double dot syntax few times.

In your source path of your .fla would be
../..
This moves up from ayumilove to com
and com to Package Test

If Game.as is located in another folder such as
PackageTest/bin then it would now be
../../bin

Extra notes again:

If in your Adobe Flash IDE, you set the source path
as ./com/ayumilove and your .as file package name has
package com.ayumilove, the compiler returns 5001 error too.

because what its trying to do is to search within
PackageTest/com/ayumilove/com/ayumilove

To solve this, either change the source path as ./
and keep the com.ayumilove in the package name of your .as

or

keep the ./com/ayumilove BUT remove the com.ayumilove
from the package name within your .as class

MORE NOTES:-

If one of your movieclip/sprite/graphic or assets in the library
is referenced to a class, make sure that it retains the path name
too.

So for instance, I have a Red MovieClip in the library,
and I have .as class separate from .fla which is located in
com.ayumilove,

right-click on the movieclip, and click properties.
Tick Export for actionscript
Expord in frame 1
and inside the class textbox, set it as com.ayumilove.Red
The ‘Red’ is the class name while com.ayumilove is the paackage
name (path/location)

Very simple explanation of get/set?

I read a lot about accessors or getters/setters, but to date I cannot really understand what they do. The language describing their use is just beyond my comprehension, not being any type of developer nor an advanced AS3 user.

Can someone provide, or point me in the direction of, a VERY SIMPLE getter/setter example that includes WHY it would be used as well as HOW to use it? I would really appreciate something small that doesn’t use just comments within functions (like “// here is where you do xyz”), but actual code (the actual doing of xyz). That way if I want to play with it and build on it I can.

Much appreciated!

It is very simple to comprehend!

First, you need to know…

What is the purpose of getter/setter function?

As the name implies, getter means to get the value,
setter means to set the value.

Getter and setter functions are special because they are “functions”
but you do not need to add the () parentheses after it.

They look like a variable without the () , but they are actually functions.

They are commonly use when you need to:-
(1) do some value manipulation before getting/setting the data.
(2) do some checking before getting/setting the data.

How do I apply getter/setter. Example please?

Below is an example (applied in a flash rpg game of mine)

Are you a RPG fan? If yes then this will be easy for you to digest.
Let’s say to calculate a hero’s bare-hand punching damage, its affected by 4 attributes:
- strength
- dexterity
- intelligence
- luck

You don’t store the damage in a variable!
Remember, it’s based on the 4 attributes above.

The below scenario, you use getter to get the manipulate damage value.
However, you can’t use setter because damage isn’t a variable

package
{

    public class Hero extends Object
    {
        private var _strength:uint;
        private var _dexterity:uint;
        private var _intelligence:uint;
        private var _luck:uint;

        public function Formula() { super(); }

        public function get damage():uint
        {
            var damage:uint;
            damage += 4 * this._strength;
            damage += 3 * this._dexterity;
            damage += 2 * this._intelligence;
            damage += 1 * this._luck;
            return damage;
        }
    }
}

Now, how about applying both getter and setter?
Let’s take a RPG (role-playing-game) bank example.
This time we use a variable to store the data.

Note: The variable name must be different than the getter/setter name.
You can’t use a variable name ‘money’ and the function name ‘money’.
This will cause Actionscript 3 naming error. To avoid it, the money variable
is set to either private/protected with an underscore prefixed.

/**
* ...
* @author ayumilove
*/

package
{
    public class Bank extends Object
    {
        private var _money:uint;

        public function Bank() { super(); }

        public function get money():uint
        {
            return this._money;
        }

        public function set money(value:int):void
        {
            this._money = value;
            if (this._money > 100) this._money = 100;
        }
    }
}

//Demo to test our bank!
package
{
    public class Main extends Object
    {
        private var _money:uint;

        public function Main()
        {
            super();
            var bank:Bank = new Bank();
            trace(bank.money); //traces 0; (before)
            bank.money += 200;
            trace(bank.money); //traces 100; (after)
        }

    }
}

As you can see above, the setter did some money manipulation,
which is , if the value banked in is greater than the maximum capacity,
then ignore the rest and store a maximum of 100.

This can be applied to other scenario such as health (HP)
whereby your health is sitting at 30/100 and you drank
a health potion that heals 200 HP, but your current HP
will not heal above 100. It becomes 100/100. Understand?

bank.money += 200;

The code snippet above looks simple and elegant,
but does lots of things, lets break this down!

bank.money += 200;
// is similar to...
bank.money = bank.money + 200;
//(setter money) = (getter money) + 200;

When you write like the above, its telling to the Flash
to get the money from the bank (getter function) and add 200 to it.

Finally, the sum of bank.money (getter function) + 200
is stored back into bank.money (setter function)

So when do I use getter setter?

Use getter/setter when you need to do manipulation to the value.

Some developers simply set their variables to private and add
the getter/setter functions. So in the future, if they need to manipulate
the data or check the data, they can write into the getter/setter.

Some developer mixed them, which is having public variables for
those data that does not need manipulation, and have private variables
with getter/setter when those data needed to be manipulated.

About the performance issue, accessing a public variable is much faster
than calling a function. Since getter/setter functions are special a little,
they have less performance overhead compare to a normal function that
is called. You can do a speed performance benchmark on those 3
accessing (public variables) vs (getter/setter) vs (normal functions).

If you are into PHP coding or some programming language that
does not support getter/setter, you will normally see a person doing this…

function getValueOfFruit()
{
return $fruitPrice;
}

Oh yeah, I just remembered something…

You avoid getter/setter functions when your function parameter has more than 1.

For instance:-

function getFruitPrice(fruitGrade,fruitAmount):void
{
return fruitGrade * fruitAmount;
}

Last but not least, it is not necessary to have both getter and setter together. They are independent! It means that you can have only getter without a setter (like the first example shown above), you code can have setter without getter (the opposite) or you can have both of them.

Talking about having setter without getter,
you can establish a few setter functions for the 4 attributes:
strength, dexterity, intelligence and luck.
But those 4 attributes does not need getter functions.

If you (the client) only wants damage by inputting values into those attributes, it would be :-
(1) setters for the 4 attributes
(2) getters for the damage attribute.

First, you need to know…

[SIZE=4][COLOR=Red][B]What is the purpose of getter/setter function?[/B][/COLOR][/SIZE]
As the name implies, getter means to get the value,
setter means to set the value.

Getter and setter functions are special because they are “functions”
but you do not need to add the () parentheses after it.

They look like a variable without the () , but they are actually functions.

They are commonly use when you need to:-
(1) do some value manipulation before getting/setting the data.
(2) do some checking before getting/setting the data.

[B][SIZE=4][COLOR=Red]
How do I apply getter/setter. Example please?
[/COLOR][/SIZE][/B]Below is an example (applied in a flash rpg game of mine)

Are you a RPG fan? If yes then this will be easy for you to digest.
Let’s say to calculate a hero’s bare-hand punching damage, its affected by 4 attributes:
- strength
- dexterity
- intelligence
- luck

You don’t store the damage in a variable!
Remember, it’s based on the 4 attributes above.

The below scenario, you use getter to get the manipulate damage value.
However, you can’t use setter because damage isn’t a variable
[PHP]
package
{

public class Hero extends Object
{
private var _strength:uint;
private var _dexterity:uint;
private var _intelligence:uint;
private var _luck:uint;

public function Formula() { super(); }

public function get damage():uint
{
var damage:uint;
damage += 4 * this._strength;
damage += 3 * this._dexterity;
damage += 2 * this._intelligence;
damage += 1 * this._luck;
return damage;
}
}
}
[/PHP]Now, how about applying both getter and setter?
Let’s take a RPG (role-playing-game) bank example.
This time we use a variable to store the data.

Note: The variable name must be different than the getter/setter name.
You can’t use a variable name ‘money’ and the function name ‘money’.
This will cause Actionscript 3 naming error. To avoid it, the money variable
is set to either private/protected with an underscore prefixed.

[PHP]
/**
* …
* @author ayumilove
*/

package
{
public class Bank extends Object
{
private var _money:uint;

public function Bank() { super(); }

public function get money():uint
{
return this._money;
}

public function set money(value:int):void
{
this._money = value;
if (this._money > 100) this._money = 100;
}
}
}

//Demo to test our bank!
package
{
public class Main extends Object
{
private var _money:uint;

public function Main()
{
super();
var bank:Bank = new Bank();
trace(bank.money); //traces 0; (before)
bank.money += 200;
trace(bank.money); //traces 100; (after)
}

}
}
[/PHP]As you can see above,
the setter did some money manipulation,
which is , if the value banked in is greater than the maximum capacity,
then ignore the rest and store a maximum of 100.

This can be applied to other scenario such as health (HP)
whereby your health is sitting at 30/100 and you drank
a health potion that heals 200 HP, but your current HP
will not heal above 100. It becomes 100/100. Understand?

[PHP]
bank.money += 200;
[/PHP]The code snippet above looks simple and elegant,
but does lots of things, lets break this down!

[PHP]
bank.money += 200;
// is similar to…
bank.money = bank.money + 200;
//[setter money] = [getter money] + 200;
[/PHP]When you write like the above, its telling to the Flash
to get the money from the bank (getter function) and add 200 to it.

Finally, the sum of bank.money (getter function) + 200
is stored back into bank.money (setter function)

[B][SIZE=4][COLOR=Red]So when do I use getter setter?
[/COLOR][/SIZE][/B]Use getter/setter when you need to do manipulation to the value.

Some developers simply set their variables to private and add
the getter/setter functions. So in the future, if they need to manipulate
the data or check the data, they can write into the getter/setter.

Some developer mixed them, which is having public variables for
those data that does not need manipulation, and have private variables
with getter/setter when those data needed to be manipulated.

About the performance issue, accessing a public variable is much faster
than calling a function. Since getter/setter functions are special a little,
they have less performance overhead compare to a normal function that
is called. You can do a speed performance benchmark on those 3
accessing (public variables) vs (getter/setter) vs (normal functions).

If you are into PHP coding or some programming language that
does not support getter/setter, you will normally see a person doing this…
[PHP]
function getValueOfFruit()
{
return $fruitPrice;
}
[/PHP]Oh yeah, I just remembered something…

You avoid getter/setter functions when your function parameter has more than 1.

For instance:-
[PHP]
function getFruitPrice(fruitGrade,fruitAmount):void
{
return fruitGrade * fruitAmount;
}
[/PHP]

Odd if statement/varialbles question?
I wasn’t even sure how to search to see if this existed.

Say I have a list (array) of functions
s_0, s_1, s_2, etc…. probably going to be 30 or so in the list.

Is there a way to do an if statement so that…

if the last function == s_0 … do this thing
else the last function == s_2 … do this other thing

i’m basically doing a linear presentation of functions
and i need the ability to go foward and backwards… but the animations/functions may be different depending on the direction, up or down in the list.

Help?

Below is a short sweet solution:
Copy and paste the code in your Flash IDE to test it out.

//3 global variables (private)
var lastCalledFunction:Function ;
var askFunctions:Array = [askApplePrice,askOrangePrice,askPearPrice];
var replyFunctions:Array = [replyApplePrice,replyOrangePrice,replyPearPrice];

//Sample Functions (Each 'reply' functions handles one particular 'ask' function)
function askApplePrice():void { trace("How much is an apple?"); }
function askOrangePrice():void { trace("How much is an orange?");}
function askPearPrice():void { trace("How much is a pear?"); }

function replyApplePrice():void { trace("Apple costs $1"); }
function replyOrangePrice():void { trace("Orange costs $1"); }
function replyPearPrice():void { trace("Pear costs $1"); }

//Business logic
function handleAskReply():void
{
	var i:int = this.askFunctions.indexOf(this.lastCalledFunction);
	if(i<0) return;
	this.replyFunctions[i]();
}

//Demo:
var randomIndex:uint = Math.random() * this.askFunctions.length;
this.lastCalledFunction = this.askFunctions[randomIndex];
this.lastCalledFunction();
this.handleAskReply();

Result / Traces

How much is an apple?
Apple costs $1

How much is an orange?
Orange costs $1

How much is a pear?
Pear costs $1

The TestStat.as class is to demonstrate on how to use this
stat system. The example below is about a hero’s health
which is manipulated by equipment and skill.
- Timeless Ring (Equipment)
- Hyperbody (Skill)
- Epic Armor (Equipment)

Stats Input: Stack and Priority
The stat system uses stack to determine whether an
equipment or skill is able to stack multiple times.
The stat system also uses priority to determine the order of
modifier being executed. Priority with the biggest value starts
first. Priority can be either negative or positive value.

Explanation
Assuming that any equipment is equipped, the hero gains
bonus stat. Timeless Ring provides the hero +50 Health.
In the TestStat.as Class, the stack is set as true.
This means, whenever the hero wears another duplicate
equipment (a second Timeless Ring) the bonus stacks.
In short, 30 (base health) + 50 (ring health) +50 (ring health).

While skill such as Hyperbody isn’t stackable (as demonstrated
in the TestStat.as where stack is false). This skill temporarily
raises hero’s health by 160% health. However, if hero attempts
to cast Hyperbody Skill twice or more), the skill bonus stat does
not stack (does not have any effect) It will be always 160%.

Epic Armor has a priority of zero, which means it will be
executed last. 148 health from rings and hyperbody is doubled,
resulting 296 health in total (modified total health).

Credits

If you use the code below, please credit me by posting the link
in your source code

TestStat.as

/**
* ...
* @author ayumilove
*/

package com.stat
{

	public class TestStat extends Object
	{
		//----------------------------------------------------------------------
		//
		//  Constructor
		//
		//----------------------------------------------------------------------

		public function TestStat ()
		{
			super (); 

			var statId:String = "Health";
			var stats : Stats = new Stats();
			stats.addStat("Health", 10, 30);

			trace("Initial Health without any modifiers");
			stats.traceStat(statId);

			trace("Modify By Adding 50 Health (Timeless Ring) 1st");
			stats.addAdditionModifierToStat
			("Health", "Timeless Ring", 50, true, 1);
			stats.traceStat(statId);

			trace("Modify By Adding 50 Health (Timeless Ring) 2nd");
			stats.addAdditionModifierToStat
			("Health", "Timeless Ring", 50, true, 1);
			stats.traceStat(statId);

			trace("Modify By Multiplying 160% Health (Hyperbody Skill) 1st");
			stats.addMultiplyModifierToStat
			("Health", "Hyperbody", 1.6, false, 2);
			stats.traceStat(statId);

			trace("Modify By Multiplying 160% Health (Hyperbody Skill) 2nd");
			stats.addMultiplyModifierToStat
			("Health", "Hyperbody", 1.6, false, 2);
			stats.traceStat(statId);

			trace("Modify By Multiplying 200% Health (Epic Armor)");
			stats.addMultiplyModifierToStat
			("Health", "Epic Armor", 2, false, 0);
			stats.traceStat(statId);

			trace("Modify By Adding 200% To Current Health (Health Elixir)");
			stats.setStatCurrentValue
			("Health", stats.getStatTotalValueModified("Health") * 2);
			stats.traceStat(statId);
		}

	}
}

Traces:-

Initial Health without any modifiers
Current Health: 10
Total Health (Unmodified): 30
Total Health (Modified): 30

Modify By Adding 50 Health (Timeless Ring) 1st
Current Health: 10
Total Health (Unmodified): 30
Total Health (Modified): 80

Modify By Adding 50 Health (Timeless Ring) 2nd
Current Health: 10
Total Health (Unmodified): 30
Total Health (Modified): 130

Modify By Multiplying 160% Health (Hyperbody Skill) 1st
Current Health: 10
Total Health (Unmodified): 30
Total Health (Modified): 148

Modify By Multiplying 160% Health (Hyperbody Skill) 2nd
Current Health: 10
Total Health (Unmodified): 30
Total Health (Modified): 148

Modify By Multiplying 200% Health (Epic Armor)
Current Health: 10
Total Health (Unmodified): 30
Total Health (Modified): 296

Modify By Adding 200% To Current Health (Health Elixir)
Current Health: 296
Total Health (Unmodified): 30
Total Health (Modified): 296

Stats.as

/**
* ...
* @author ayumilove
*/

package com.stat
{

	public class Stats extends Object
	{
		//----------------------------------------------------------------------
		//
		//  Private properties
		//
		//----------------------------------------------------------------------

		private var _stats:Object = { };

		//----------------------------------------------------------------------
		//
		//  Constructor
		//
		//----------------------------------------------------------------------

		public function Stats() { super(); }

		//----------------------------------------------------------------------
		//
		//  Add/Remove Stats
		//
		//----------------------------------------------------------------------

		public function addStat(statId:String,current:Number,total:Number):void
		{
			if (this._stats[statId]) return;
			var stat:Stat = new Stat();
			stat.id = statId;
			stat.current = current;
			stat.totalUnmodified = total;
			this._stats[statId] = stat;
		}

		public function removeStat(statId:String):void
		{
			if (!this._stats[statId]) return;
			this._stats[statId] = null;
			delete this._stats[statId];
		}

		//----------------------------------------------------------------------
		//
		//  Get/Set Value (Current and Total)
		//
		//----------------------------------------------------------------------

		public function getStatCurrentValue(statId:String):Number
		{
			if (!this._stats[statId]) return 0;
			var stat:Stat = this._stats[statId];
			return stat.current;
		}

		public function setStatCurrentValue(statId:String,value:Number):void
		{
			if (!this._stats[statId]) return ;
			var stat:Stat = this._stats[statId];
			stat.current = value;
		}

		public function getStatTotalValueUnmodified(statId:String):Number
		{
			if (!this._stats[statId]) return 0;
			var stat:Stat = this._stats[statId];
			return stat.totalUnmodified;
		}

		public function setStatTotalValueUnmodified(statId:String,value:Number):void
		{
			if (!this._stats[statId]) return ;
			var stat:Stat = this._stats[statId];
			stat.totalUnmodified = value;
		}

		public function getStatTotalValueModified(statId:String):Number
		{
			if (!this._stats[statId]) return 0;
			var stat:Stat = this._stats[statId];
			return stat.totalModified;
		}

		//----------------------------------------------------------------------
		//
		//  Add/Remove Modifier
		//
		//----------------------------------------------------------------------

		public function addAdditionModifierToStat(
		statId:String, modifierId:String, value:Number,
		stackable:Boolean = true, priority:int = 0):void
		{
			var modifier:Modifier = new AdditionModifier();
			this.setModifierToStat(
			statId,modifier,modifierId,value,stackable,priority);
		}

		public function addMultiplyModifierToStat(
		statId:String, modifierId:String, value:Number,
		stackable:Boolean = true, priority:int = 0):void
		{
			var modifier:Modifier = new MultiplyModifier();
			this.setModifierToStat(
			statId,modifier,modifierId,value,stackable,priority);
		}

		public function removeModifierFromStat(
		statId:String, modifierId:String):void
		{
			if (!this._stats[statId]) return;
			var stat:Stat = this._stats[statId];
			stat.removeModifier(modifierId);
		}

		//----------------------------------------------------------------------
		//
		//  Helper Methods
		//
		//----------------------------------------------------------------------

		private function setModifierToStat(
		statId:String, modifier:Modifier, modifierId:String, value:Number,
		stackable:Boolean, priority:int):void
		{
			if (!this._stats[statId]) return;
			var stat:Stat = this._stats[statId];
			modifier.id = modifierId;
			modifier.value = value;
			modifier.stackable = stackable;
			modifier.priority = priority;
			stat.addModifier(modifier);
		}

		public function traceStat(statId:String):void
		{
			if (!this._stats[statId]) return;

			trace("Current " + statId + ": " +
			this.getStatCurrentValue(statId));

			trace("Total " + statId + " (Unmodified): " +
			this.getStatTotalValueUnmodified(statId));

			trace("Total " + statId + " (Modified): " +
			this.getStatTotalValueModified(statId));

			trace("");
		}

	}
}

Stat.as

/**
* ...
* @author ayumilove
*/

package com.stat
{

	public class Stat extends Object
	{
		//----------------------------------------------------------------------
		//
		//  Public properties
		//
		//----------------------------------------------------------------------

		public function get id():String
		{
			return this._id;
		}

		public function set id(value:String):void
		{
			this._id = value;
		}

		public function get current():Number
		{
			return this._current;
		 }

		public function set current(value:Number):void
		{
			this._current = value;

			if (this._current > this._totalModified)
			{
				this._current = this._totalModified;
			}
		}

		public function get totalModified():Number
		{
			return this._totalModified;
		}

		public function get totalUnmodified():Number
		{
			return this._totalUnmodified;
		}

		public function set totalUnmodified(value:Number):void
		{
			this._totalUnmodified = value;
			this.updateTotalModified();
		}

		//----------------------------------------------------------------------
		//
		//  Private properties
		//
		//----------------------------------------------------------------------

		private var _id:String = "";
		private var _current:Number = 0;
		private var _totalModified:Number = 0;
		private var _totalUnmodified:Number = 0;
		private var _modifiers:Object = { };

		//----------------------------------------------------------------------
		//
		//  Constructor
		//
		//----------------------------------------------------------------------

		public function Stat() { super(); }

		//----------------------------------------------------------------------
		//
		//  Add/Remove/Update Modifier
		//
		//----------------------------------------------------------------------

		public function addModifier(modifier:Modifier):void
		{
			if (!this._modifiers[modifier.id])
			{
				this._modifiers[modifier.id] = modifier;
			}
			else
			{
				modifier = this._modifiers[modifier.id];
				if (modifier.stackable) { modifier.stack++; }
			}

			this.updateTotalModified();
		}

		public function removeModifier(modifierId:String):void
		{
			var modifier:Modifier = this._modifiers[modifierId];

			if (modifier)
			{
				modifier.stack--;
				if (modifier.stack < 1)
				{
					this._modifiers[modifierId] = null;
					delete this._modifiers[modifierId];
				}
			}
			this.updateTotalModified();
		}

		private function updateTotalModified():void
		{
			this._totalModified = this._totalUnmodified;
			var modifiers:Array = [];

			for (var property:String in this._modifiers)
			{
				modifiers.push(this._modifiers[property]);
			}

			modifiers.sortOn("priority", Array.NUMERIC);

			var modifier:Modifier;
			var i:int = modifiers.length;

			while (i--)
			{
				modifier = modifiers[i];
				this._totalModified = modifier.modify(this._totalModified);
			}

		}

	}
}

Modifier

/**
* ...
* @author ayumilove
*/

package com.stat
{

	public class Modifier extends Object
	{
		//----------------------------------------------------------------------
		//
		//  Public properties
		//
		//----------------------------------------------------------------------

		public function get id():String
		{
			return this._id;
		}

		public function set id(value:String):void
		{
			this._id = value;
		}

		public function get value():Number
		{
			return this._value;
		}

		public function set value(value:Number):void
		{
			this._value = value;
		}

		public function get stack():Number
		{
			return this._stack;
		}

		public function set stack(value:Number):void
		{
			this._stack = value;
		}

		public function get stackable():Boolean
		{
			return this._stackable;
		}

		public function set stackable(value:Boolean):void
		{
			this._stackable = value;
		}

		public function get priority():int
		{
			return this._priority;
		}

		public function set priority(value:int):void
		{
			this._priority = value;
		}

		//----------------------------------------------------------------------
		//
		//  Protected properties
		//
		//----------------------------------------------------------------------

		protected var _id:String = "";
		protected var _value:Number = 0;
		protected var _stack:Number = 1;
		protected var _stackable:Boolean;
		protected var _priority:int;

		//----------------------------------------------------------------------
		//
		//  Constructor
		//
		//----------------------------------------------------------------------

		public function Modifier() { super(); }

		//----------------------------------------------------------------------
		//
		//  Public methods
		//
		//----------------------------------------------------------------------

		public function modify(value:Number):Number
		{
			return value;
		}

	}
}

AdditionModifier.as

/**
* ...
* @author ayumilove
*/

package com.stat
{

	public class AdditionModifier extends Modifier
	{
		//----------------------------------------------------------------------
		//
		//  Constructor
		//
		//----------------------------------------------------------------------

		public function AdditionModifier() { super(); }

		//----------------------------------------------------------------------
		//
		//  Public methods
		//
		//----------------------------------------------------------------------

		public override function modify(value:Number):Number
		{
			value += super._value * stack;
			return value;
		}

	}
}

MultiplyModifier.as

/**
* ...
* @author ayumilove
*/

package com.stat
{

	public class MultiplyModifier extends Modifier
	{
		//----------------------------------------------------------------------
		//
		//  Constructor
		//
		//----------------------------------------------------------------------

		public function MultiplyModifier() { super(); }

		//----------------------------------------------------------------------
		//
		//  Public methods
		//
		//----------------------------------------------------------------------

		public override function modify(value:Number):Number
		{
			value *= super._value * stack;
			return value;
		}

	}
}

import flash.text.TextField;

var ayumiloveMessage:Array = ["welcome to","ayumilove","world"];

var textField1:TextField = new TextField();
var textField2:TextField = new TextField();
var textField3:TextField = new TextField();

textField1.y = 0;
textField2.y = 30;
textField3.y = 60;

super.addChild(textField1);
super.addChild(textField2);
super.addChild(textField3);

for(var i:int=0; i < ayumiloveMessage.length; i++)
{
	this["textField"+(i+1)].text = ayumiloveMessage[i];
}

The code below prevents a user from moving diagonal.
The sprite is constricted to move only left,right, up and down
at any point of time. This is to address a fellow Kirupan issue
in this thread.

import flash.display.Sprite;
import flash.events.KeyboardEvent;

var speed:uint = 10;
var keyLock:uint;

var sp:Sprite = new Sprite();
sp.graphics.beginFill(0xFF0000);
sp.graphics.drawRect(0,0,25,25);
sp.graphics.endFill();
super.addChild(sp);

super.stage.addEventListener(KeyboardEvent.KEY_DOWN, this.keyDownHandler);

function keyDownHandler(event:KeyboardEvent):void
{
	switch(event.keyCode)
	{
		case Keyboard.LEFT 	: sp.x -= this.speed; break;
		case Keyboard.RIGHT : sp.x += this.speed; break;
		case Keyboard.UP 	: sp.y -= this.speed; break;
		case Keyboard.DOWN 	: sp.y += this.speed; break;
		default 			: break;
	}
}

Preview SWF Here
http://megaswf.com/serve/41252/